cat • methoddecl

Method Declaration

Procedures

[ FAST ] [ STATIC ] { PUBLIC | PRIVATE } { PROCEDURE | SUB } Identifier ( [ [ BYREF ] Parameter AS Datatype [ , … ] ] [ , ] [ OPTIONAL [ BYREF ] Optional Parameter AS Datatype [ , … ] ] [ , ] [ ... ] ) ... END

This declares a procedure, i.e. a method that returns nothing.

The END keyword indicates the end of the procedure.

Functions

[ FAST ] [ STATIC ] { PUBLIC | PRIVATE } { FUNCTION | PROCEDURE | SUB } Identifier ( [ [ BYREF ] Parameter AS Datatype [ , … ] ] [ , ] [ OPTIONAL [ BYREF ] Optional Parameter AS Datatype [ , … ] ] [ , ] [ ... ] ) AS Datatype ... END

This declares a function, i.e. a method that returns a value.

The END keyword indicates the end of the function.

The datatype of the return value must be specified.

Of course, these declarations must be written on a unique line. They are separated there so that it is readable.

Use the /wiki/cat/return keyword to terminate the function and pass the return value back to the caller.

Examples

Function Calc(fX As Float) As Float
  Return Sin(fX) * Exp(- fX)
End

Public Sub Button1_Click()
  Print Calc(0);; Calc(0.5);; Calc(1)
End

0 0.290786288213 0.309559875653

Method Access

The method is accessible everywhere in the class it is declared.

  • If the PUBLIC keyword is specified, it is also accessible to the other classes having a reference to an object of this class.

  • If the STATIC keyword is specified, the method can only access to the static variables of the class.

Method Arguments

All method arguments are separated by commas.

  • If the OPTIONAL keyword is specified, all parameters after the keywords are optional. You can specify a default value after the parameter declaration by using the equal sign.

  • If the parameters list end with ..., then the method can take extra arguments. Every additional argument passed to the method is accessible with the Param class.

Examples

Static Public Procedure Main()
...
Public Function Calc(fA As Float, fB As Float) As Float
...
Private Sub DoIt(sCommand As String, Optional bSaveIt As Boolean = True)
...
Static Private Function MyPrintf(sFormat As String, ...) As Integer

Arguments Passed By Reference

When the BYREF keyword is specified, the argument must be an assignment expression that will be modified by the called function.

Examples

Sub ConvPixelToCentimeter(ByRef Value As Float, Dpi As Integer)

  Value = Value / Dpi * 2.54

End

Public Sub Main()

  Dim Size As Float

  Size = 256
  ConvPixelToCentimeter(ByRef Size, 96)
  Print Size

End

6.773333333333

If you do not specify BYREF at function call, then the argument is passed by value, even if BYREF was specified at function declaration.

In other words: the called function allows an argument to be passed by reference, whereas the caller decides it.

Just In-Time Compilation

Since 3.2

If the FAST keyword is used, then the method will be optimized by the Just In Time Compiler.

See also